From: Mikhail Grigorev <redacted>
Date: Sun, 30 Oct 2022 19:51:29 +0000 (+0500)
Subject: Added for Windows implemenated script download-ggml-model.cmd
X-Git-Tag: upstream/1.7.4~1866
X-Git-Url: https://git.djapps.eu/?a=commitdiff_plain;h=b26345cc7b988af76651a56d6826bd44d1db5ca7;p=pkg%2Fggml%2Fsources%2Fwhisper.cpp

Added for Windows implemenated script download-ggml-model.cmd
---

diff --git a/models/download-ggml-model.cmd b/models/download-ggml-model.cmd
new file mode 100644
index 00000000..bc64e2ac
--- /dev/null
+++ b/models/download-ggml-model.cmd
@@ -0,0 +1,63 @@
+@echo off
+
+pushd %~dp0
+set models_path=%CD%
+popd
+
+set argc=0
+for %%x in (%*) do set /A argc+=1
+
+set models=tiny.en tiny base.en base small.en small medium.en medium large
+
+if %argc% neq 1 (
+  echo.
+  echo Usage: download-ggml-model.cmd model
+  CALL :list_models
+  goto :eof
+)
+
+set model=%1
+
+for %%b in (%models%) do ( 
+  if "%%b"=="%model%" (
+    CALL :download_model
+    goto :eof
+  )
+)
+
+echo Invalid model: %model%
+CALL :list_models
+goto :eof
+
+:download_model
+echo Downloading ggml model %model%...
+
+cd %models_path%
+
+if exist "ggml-%model%.bin" (
+  echo Model %model% already exists. Skipping download.
+  goto :eof
+)
+
+PowerShell -NoProfile -ExecutionPolicy Bypass -Command "Invoke-WebRequest -Uri https://ggml.ggerganov.com/ggml-model-whisper-%model%.bin -OutFile ggml-%model%.bin"
+
+if %ERRORLEVEL% neq 0 ( 
+  echo Failed to download ggml model %model%
+  echo Please try again later or download the original Whisper model files and convert them yourself.
+  goto :eof
+)
+
+echo Done! Model %model% saved in %models_path%\models\ggml-%model%.bin
+echo You can now use it like this:
+echo main.exe -m %models_path%\models\ggml-%model%.bin -f %models_path%\samples\jfk.wav
+
+goto :eof
+
+:list_models
+  echo.
+  echo Available models:
+  (for %%a in (%models%) do ( 
+    echo %%a 
+  ))
+  echo.
+  exit /b